Think or Swim Indicators

[MC]

TTM Squeeze

declare lower;
input Length = 20;
input price = close;
######################
def e1 = (Highest(High, length) + Lowest(low, length)) / 2 + Average(close, length);
def osc = Inertia(price - e1 / 2, length);
plot oscp = osc;

def diff = reference bollingerbands(length = 20)."upperband" - reference KeltnerChannels."Upper_Band";
plot mid = 0;
mid.assignValueColor(if diff >= 0 then Color.UPTICK else Color.DOWNTICK);

#oscp.assignValueColor(if osc[1] < osc[0] then Color.CYAN else Color.magenta);
oscp.assignValueColor(if osc[1] < osc[0] then
if osc[0] >= 0 then
#UpPos
createColor(0, 255, 255) else
#UpNeg
createColor(204, 0, 204)
else if osc[0] >= 0 then
#DnPos
createColor(0, 155, 155) else
#DnNeg
createColor(255, 155, 255));

oscp.setPaintingStrategy( PaintingStrategy.HISTOGRAM);
mid.setPaintingStrategy(PaintingStrategy.POINTS);

[MC]

I didn't code this or any indicator that may become posted here! Perhaps you can find more info using the link in the helpful link section.

I did notice my TOS platform ran slower due to the heavy calculations, perhaps the code is a bit fat...I dunno.

[Timmyb]

Well it took me a while but i dived into thinkscript. And luckily it is much differnt than ninja.I can usually trudge my way through. Anyway this hasnt been fully tested but it appears to work well.

If any of you listen to shadow trader he uses certain pivot points. Well i coded them for tos now.

It is adjustable for open times. I suggest setting chart to day only then adjusting time to that.

It is also adjustable to show pviots above or below. Basically when you have allot of pivots the screen gets squished and you lose perspective. Well you can adjust it so it only shows the pivots when the price is towards them. as in its only gonna show s1 pivot and s2 until price break say s1 then you will see pivot s1, and s2.

thanks
tim

here is a pic with the dynamic turned on, hence only three levels but no squished chart


here is with off so you see all the lines. note the chart kinda squished



and the code

#built by timmyb, tradersbase.com

input DynamicHide = {"No", default "Yes"};
input showOnlyToday = YES;
input Market_Open_Time = 0830;
input Market_Close_Time = 1616;


def h = DynamicHide;
def day = getDay();
def lastDay = getLastDay();
def isToday = if(day == lastDay, 1, 0);
def shouldPlot = if(showOnlyToday and isToday, 1, if(!showOnlyToday, 1, 0));

def pastOpen = if((secondsTillTime(Market_Open_Time) > 0), 0, 1);
def pastClose = if((secondsTillTime(Market_Close_Time) > 0), 0, 1);
def marketOpen = if(pastOpen and !pastClose, 1, 0);
def firstBar = if (day[1] != day, 1, 0);

def closingBell = if secondsTillTime(Market_Close_Time)[1] > 0 and
secondsTillTime(Market_Close_Time) <= 0 or
(secondsTillTime(Market_Close_Time)[1] < secondsTillTime(Market_Close_Time)
and secondsTillTime(Market_Close_Time)[1] > 0) then 1 else 0;

rec lclose = if IsNaN(close[-1]) then lclose[1] else close;
rec regHoursHigh = if(high > regHoursHigh[1] and marketOpen, high,
if(marketOpen and !firstBar, regHoursHigh[1], high));
rec regHoursLow = if(low < regHoursLow[1] and marketOpen, low,
if(marketOpen and regHoursLow[1] > 0 and !firstBar, regHoursLow[1], low));

rec runningClose = compoundValue(1, if closingbell then close[1] else runningClose[1], close);
rec prevClose = compoundValue(1, if closingBell then runningClose else prevClose[1], close);
rec prevHigh = compoundValue(1, if closingBell then regHoursHigh[1] else prevHigh[1], high);
rec prevLow = compoundValue(1, if closingBell then regHourslow[1] else prevlow[1], low);
rec prevHigh2 = compoundValue(1, if closingBell then prevHigh[1] else prevHigh2[1], high);
rec prevLow2 = compoundValue(1, if closingBell then prevLow[1] else prevlow2[1], low);


plot pivot = if shouldPlot then (prevHigh + prevClose + prevLow) / 3 else double.nan;
pivot.SetStyle(curve.FIRM);
pivot.SetDefaultColor(color.BLACK);



plot s1 = if shouldPlot then (2 * pivot) - prevHigh else double.nan;
s1.SetStyle(curve.FIRM);
s1.SetDefaultColor(color.dark_green);

plot r1 = if shouldPlot then (2 * pivot) - prevLow else double.nan;
r1.SetStyle(curve.FIRM);
r1.SetDefaultColor(color.DaRK_RED);

plot r2 = if shouldPlot then pivot + ( r1 - s1) else double.nan;
r2.SetStyle(curve.FIRM);
r2.SetDefaultColor(color.DaRK_RED);

plot s2 = if shouldPlot then pivot - ( r1 - s1) else double.nan;
s2.SetStyle(curve.FIRM);
s2.SetDefaultColor(color.DaRK_GREEN);

plot s3 = if shouldPlot then prevLow - 2 * (prevHigh - pivot) else double.nan;
s3.SetStyle(curve.FIRM);
s3.SetDefaultColor(color.DaRK_GREEN);

plot r3 = if shouldPlot then prevHigh + 2 * (pivot - prevLow) else double.nan;
r3.SetStyle(curve.FIRM);
r3.SetDefaultColor(color.DaRK_RED);

pivot.setHiding(h and (lclose > r2 or lclose < s2));
r1.setHiding(h and lclose < s1);
r2.setHiding(h and lclose < r1);
r3.setHiding(h and lclose < r2);

s1.setHiding(h and lclose > r1);
s2.setHiding(h and lclose > s1);
s3.setHiding(h and lclose > s2);

[cire2222]

sweet. good job tim. you the man

[Timmyb]

here is another. I did not create this one but it was available for free so. I figure its ok to post here.

I am posting this one because
it has to do with shadow trader also.



displays advancing declining ratios, issues for nyse or nasdaq. can The pic shows all options. But i tend to just watch one

and the code


declare lower;

input display = {default ADIssuesRatio, ADIssues, ADVolumeRatio, ADVolume};
input market = {default NYSE, NASDAQ};

def advancing = if(market, close("$advn/q"), close("$advn"));
def declining = if(market, close("$decn/q"), close("$decn"));
def advVolume = if(market, close("$uvol/q"), close("$uvol"));
def decVolume = if(market, close("$dvol/q"), close("$dvol"));

plot Breadth;

switch(display) {
case ADIssuesRatio:
Breadth = if(advancing > declining, (advancing / declining), (-declining / advancing));
case ADIssues:
Breadth = advancing - declining;
case ADVolume:
Breadth = advVolume - decVolume;
case ADVolumeRatio:
Breadth = if( advVolume > decVolume, (advVolume / decVolume), (-decVolume / advVolume));
}

Breadth.AssignValueColor(if Breadth >= 0.0 then color.green else color.red);
Breadth.SetPaintingStrategy(paintingStrategy.HISTO GRAM);
Breadth.SetLineWeight(3);

plot ZeroLine = 0.0;
ZeroLine.SetDefaultColor(color.white);

[Timmyb]

In a quest to make sure the pivots are perfect I also designed one that you enter the price yourself.

here is a screen shot of settings



you enter those prices and it posts the pivot points. the day setting just extends the lines. dynamic works the same as first. if on it will hide the ones price hasn't moved to.

here is code

#built by timmyb, tradersbase.com

input DynamicHide = {"No", default "Yes"};
input showOnlyToday = YES;
input Previous_High = 800.00;
input Previous_Low = 800.00;
input Previous_Settlement = 800.00;


def h = DynamicHide;
def day = getDay();
def lastDay = getLastDay();
def isToday = if(day == lastDay, 1, 0);
def shouldPlot = if(showOnlyToday and isToday, 1, if(!showOnlyToday, 1, 0));

rec lclose = if IsNaN(close[-1]) then lclose[1] else close;

plot pivot = if shouldPlot then (Previous_High + Previous_Settlement + Previous_Low)/3 else double.nan;
pivot.SetStyle(curve.FIRM);
pivot.SetDefaultColor(color.DARK_GRAY);

plot s1 = (2 * pivot) - Previous_High ;
s1.SetStyle(curve.FIRM);
s1.SetDefaultColor(color.dark_green);

plot r1 = (2 * pivot) - Previous_Low;
r1.SetStyle(curve.FIRM);
r1.SetDefaultColor(color.DaRK_RED);

plot r2 = pivot + ( r1 - s1) ;
r2.SetStyle(curve.FIRM);
r2.SetDefaultColor(color.DaRK_RED);

plot s2 = pivot - ( r1 - s1) ;
s2.SetStyle(curve.FIRM);
s2.SetDefaultColor(color.DaRK_GREEN);

plot s3 = Previous_Low - 2 * (Previous_High - pivot);
s3.SetStyle(curve.FIRM);
s3.SetDefaultColor(color.DaRK_GREEN);

plot r3 = Previous_High + 2 * (pivot - Previous_Low) ;
r3.SetStyle(curve.FIRM);
r3.SetDefaultColor(color.DaRK_RED);

pivot.setHiding(h and (lclose > r2 or lclose < s2));
r1.setHiding(h and lclose < s1);
r2.setHiding(h and lclose < r1);
r3.setHiding(h and lclose < r2);

s1.setHiding(h and lclose > r1);
s2.setHiding(h and lclose > s1);
s3.setHiding(h and lclose > s2);

[Boudreaux]

Thanks...very cool. The squeeze doesn't load on the screen for some reason and it's red in the list of active indicators. Wonder if I'm doing something wrong.

Any ideas?

[cire2222]

it could be that you need to go in and delete possible spaces in the code that break it up

[ThinkScripter]

The new TOS Script Editor doesn't like cut and paste from a web page. You'll need to paste into Notepad first to strip out any hidden formatting and then paste into TOS.

You can find my scripts at www.thinkscripter.com, most of which are public. I do politely ask that you leave the header intact if you republish the code here or elsewhere.
-Eric

[MC]

Originally Posted by ThinkScripter

The new TOS Script Editor doesn't like cut and paste from a web page. You'll need to paste into Notepad first to strip out any hidden formatting and then paste into TOS.

You can find my scripts at www.thinkscripter.com, most of which are public. I do politely ask that you leave the header intact if you republish the code here or elsewhere.
-Eric

Thanks for the heads up. Feel free to post your scripts here if you want.
I get a good amount of search engine hits on thinkscript and think or swim so it may help your hit count also. I normally don't like links in signatures but feel free since you provide many free scripts.

PS I wouldn't turn down a free pro level subscription to your site if you offered.

Keep up the good work.